Conexión MC68HC11 y HP-48

En esta página se ofrecen unos programas y comentarios para conectar sistemas basados en el microcontrolador MC68HC11 y una calculadora HP-48 a través de los puertos serie. Principalmente se explican los conceptos básicos de funcionamiento de los programas que se necesitan en los dos sistemas aunque también se proporciona un programa para la HP-48 que muestra en el display lo que le llega por el puerto serie y envía los códigos asignados a cada tecla.

Se supone que ya se dispone de un sistema basado en MC68HC11, una calculadora HP-48 y los cables de conexión de cada uno de ellos a un puerto serie del ordenador. En el caso de la tarjeta CT6811 de Microbótica, ya se incluye un cable con conexiones telefónicas RJ11 y un conversor a DB9; para las HP-48 es bastante sencillo adquirir un cable con un terminador DB9.

Además, necesitaremos un cable que nos permita conectar ambos sistemas por los teminadores DB9 en el que se permuten las líneas de envío y recepción (lo que se conoce como modem nulo). Por tanto, se necesitarán dos terminadores DB9 macho y cable (con uno de tres hilos es suficiente).

Tenemos que preparar un cable que una las señales de masa de los dos conectores (pin número 5 en los DB9) e intercambie las de recepción y envío (pines 2 y 3) para que un dispositivo reciba lo que el otro está enviando y viceversa. Las conexiones quedan como se muestra en la siguiente figura.

En el lado del MC68HC11 vamos a utilizar el SCI que es el interfaz serie asíncrono que dispone este microcontrolador. Su programación es muy sencilla si se tiene algo de cuidado para no machacar los valores que se están enviando y recibiendo.

Vamos a utilizar sólamente tres registros internos del MC68HC11 para controlar la comunicación:

• El registro BAUD (situado en la posición de memoria $102B) para fijar la velocidad a la que se realizará la comunicación. Con $30 estamos seleccionando una comunicación a 9600 baudios, con $33 a 1200 baudios (suponiendo que se está trabajando a 8 MHz). El MC68HC11 permite otras velocidades pero éstas son compatibles con las que nos ofrece la HP-48.

BAUD EQU $2B ; Registro de velocidad LDX #$1000 ; Apunta a los registros de control LDAA #$30 ; 9600 baudios * LDAA #$33 ; 1200 baudios STAA BAUD,X ; Configura la velocidad

• El registro SCSR (situado en la posición de memoria $102E), registro de estado del SCI, para esperar a que se haya concluido un envío o recepción anterior. En el caso del envío esperaremos a que se active (se ponga a 1) el bit más significativo con la máscara $80; en el caso de la recepción esperaremos a que se active (se ponga a 1) el bit 5 con la máscara $20.
• El registro SCDR (situado en la posición de memoria $102F), registro de datos del SCI, para recuperar o enviar el dato.

SCSR EQU $2E ; Registro de estado del SCI SCDR EQU $2F ; Registro de datos del SCI LDX #$1000 ; Apunta a los registros de control * ----------------------------------------------------------------------- * Envía el carácter del acumulador A por el puerto serie SCI * ----------------------------------------------------------------------- sendc BRCLR SCSR,X $80 sendc ; Espera a que termine un envío anterior STAA SCDR,X ; Envía el carácter RTS * ----------------------------------------------------------------------- * Lee un carácter que llega por el puerto serie SCI en el acumulador A * ----------------------------------------------------------------------- readc BRCLR SCSR,X $20 readc ; Espera a que se reciba un carácter LDAA SCDR,X ; Lee el carácter recibido RTS

Estas dos rutinas envían y reciben, respectivamente, lo que esté en el acumulador A del MC68HC11. Su utilización es muy sencilla, sólo comentar que en la recepción, el flujo del programa queda detenido esperando a que se reciba un dato un por puerto serie. Si no se desea esta espera, puede utilizarse un esquema basado en interrupciones para detectar cuándo ha llegado un dato y recogerlo en ese momento.

El siguiente programa que puede obtenerse directamente desde aquí, espera la pulsación del bumper izquierdo (en el bit 0 del puerto E). Una vez que se pulsa, el programa envía la cadena HOLA por el puerto serie y se queda a la espera de los caracteres que le llegan, haciendo eco por el mismo puerto de lo que le va llegando. Se incluye el fichero wait.inc que incorpora rutinas para efectuar pausas. Esta facilidad de ficheros include sólo puede utilizarse desde el ensamblador Ras, si se utiliza otro programa ensamblador siempre puede incluirse a mano desde el editor.

* -----------------------------------------------------------------------  
* hp48c.asm			2001/04/16
*
* Prueba de las comunicaciones serie asíncronas de HC11.
*	- Envía una secuencia de caracteres por el puerto serie.
*	- Hace eco de lo que le llega por el puerto serie y hace una
*	  pausa entre cada eco.
* -----------------------------------------------------------------------

PORTA	EQU $00			; Dirección del puerto A
PORTE	EQU $0A			; Dirección del puerto E

BAUD	EQU $2B			; Registro de velocidad
SCSR	EQU $2E			; Registro de estado del SCI
SCDR	EQU $2F			; Registro de datos del SCI

	ORG $0000		; Programa en RAM interna


	LDX #$1000		; Apunta a los registros de control

	LDAA #$30		; 9600 baudios
*	LDAA #$33		; 1200 baudios
	STAA BAUD,X		; Configura la velocidad

	BSET PORTA,X $40	; Enciende el LED de la CT6811
pulsa	BRCLR PORTE,X $01 pulsa	; Espera a que se pulse el bumper izq

	LDAA #'H		; Envía la cadena "HOLA"
	BSR sendc
	LDAA #'O'
	BSR sendc
	LDAA #'L'
	BSR sendc
	LDAA #'A'
	BSR sendc

eco	BSET PORTA,X $40	; Enciende el LED de la CT6811
	BSR readc		; Lee un carácter
	BSR sendc		; Lo vuelve a enviar

	BCLR PORTA,X $40	; Apaga el LED
	BSR f_wait		; Hace un pausa

fin	BRA eco


* -----------------------------------------------------------------------
* Envía el carácter del acumulador A por el puerto serie SCI
* -----------------------------------------------------------------------

sendc	BRCLR SCSR,X $80 sendc	; Espera a que termine un envío anterior
	STAA SCDR,X		; Envía el carácter
	RTS


* -----------------------------------------------------------------------
* Lee un carácter que llega por el puerto serie SCI en el acumulador A
* -----------------------------------------------------------------------

readc	BRCLR SCSR,X $20 readc	; Espera a que se reciba un carácter
	LDAA SCDR,X		; Lee el carácter recibido
	RTS


* -----------------------------------------------------------------------
* Incluye rutinas de pausa
* -----------------------------------------------------------------------

	include wait.inc

	END

La programación en el lado de la HP-48 es también muy sencilla. Vamos a utilizar estas cinco llamadas relacionadas con la utilización del puerto serie:

• n SRECV, recibe n caracteres por el puerto serie (el valor n lo toma de la pila). Devuelve un 1 en la cima de la pila si la comunación ha ido bien; un 0 si se han perdido datos o se han producido errores. En el segundo nivel de la pila, encontraremos una cadena con los caracteres recibidos o vacía si hubo errores.
• cadena XMIT, envía cadena por el puerto serie (en la pila la cadena debe estar entre comillas doble como es habitual en RPL). Devuelve un 1 en la cima de la pila si no hubo errores y un 0 en caso contrario, en este segundo caso, en el segundo nivel de la pila estará la cadena (todo o parte) que no se pudo enviar.
• BUFLEN, devuelve, en la cima de la pila, 0 ó 1 si hubo error o no, respectivamente, y el número de caracteres pendientes en el buffer en el segundo nivel. Esto es cierto en el caso de que las comunicaciones estén abiertas.
• OPENIO, abre las comunicaciones serie. No utliza la pila.
• CLOSEIO, cierra las comunicaciones serie. No utliza la pila.

Antes de comenzar con las pruebas es recomendable que nos aseguremos que están bien los parámetros de comunicación de la HP-48. Se podría realizar también por programa pero es bastante común determinar los parámetros mediante variables. En cualquier caso, verifíquese que la comunicación se establece a través del cable y no con infrarrojos (opción Port: Wire), en formato binario a 9600 baudios (o la velocidad que cada uno prefiera) sin paridad.

Se han utilizado ocho variables (entre datos y programas) en la HP-48. A continuación se describe para qué sirve cada una de ellas.

• HC11, puede entenderse como el programa principal. Si se ejecuta la HP-48 permanece a la espera vigilando que se reciban caracteres por el puerto serie o se pulse una tecla. La tecla CANCEL permite salir del programa. Se está vigilando continuamente que se produzcan estos eventos, el que lo considere oportuno puede modificar directamente el código para establecer una pausa en el bucle principal. Los datos recibidos se van mostrando en el display en formato de 7 líneas; se lleva un contador de trama y se deja una l&iaacute;nea en blanco para facilitar su lectura.
• SELTI, selecciona el tipo de datos que van a llegar, o mejor, el tipo de interpretación que vamos a hacer de esos datos. Puede ser Caracteres, muestra lo que llega como un carácter, Números de 8 bits, lo convierte a número, o Strings, muestra todo lo que llega como caracteres hasta que se vacía el buffer. Una vez ejecutado, el programa muestra un menú desde el que se puede seleccionar el tipo. Actualiza las variables TIPO y LEE.
• TIPO, almacena el valor 1, 2 ó 3 relacionado con el tipo de datos a recibir, Caracteres, Números de 8 bits o Strings, respectivamente.
• LEE, programa en el que se almacena la lectura a realizar dependiendo del tipo de datos seleccionado. Puede incluir llamadas a los programas LCHR, si son caracteres, LNUM, si son números, o LSTR, si son cadenas.
• ->CAR, convierte el código fila/columna/plano utilizado para designar las teclas de la HP-48 en el valor ASCII representado en cada tecla (letras mayúsculas, números y s´mbolos especiales). Toma el valor a convertir de la pila y devuelve el valor convertido en la pila.
• LCHR, programa que lee un solo carácter del puerto serie. Lo devuelve en la cima de la pila.
• LNUM, programa que lee un solo carácter del puerto serie y lo convierte a su correspondiente valor numérico. Lo devuelve en la cima de la pila.
• LSTR, programa que lee una cadena de caracteres del puerto serie (hasta que se vacía el buffer) y los concatena en un string que devuelve en la cima de la pila.

Puede ver el código directamente en esta página o descargar el directorio completo que incluye los fuentes para la HP-48 en modo texto o en binario. Para instalarlo en la HP-48 siga el procedimiento habitual.

* -----------------------------------------------------------------------  
  HC11
* -----------------------------------------------------------------------
    « CLLCD OPENIO RCLF -40 CF DEPTH -> Z
      «
        IFERR -1
          WHILE 1
          REPEAT
            IF BUFLEN DROP
            THEN
	      LEE
	      440 .1 BEEP
	      SWAP 1 + "0" OVER
	      ->STR + DUP SIZE DUP 1 - SWAP SUB "->" +
	      ROT + OVER 7 MOD 1 + "" OVER 1 + DISP DISP
            ELSE
              IF KEY
              THEN
	        ->CAR XMIT
		IF NOT
		THEN
		  DROP
		END
              END
            END
          END
        THEN
	  DEPTH Z - DROPN
        END
      » STOF CLOSEIO
    »


* -----------------------------------------------------------------------
  SELTI
* -----------------------------------------------------------------------
    « "TIPO DE DATOS"
      { {"Caracteres" 1 } {"Números 8 bits" 2} { "Strings" 3 } }
      TIPO
      CHOOSE
      IF 0 <>
      THEN
        CASE
	  DUP 1 ==
          THEN
            « LCHR »
          END
	  DUP 2 ==
          THEN
	    « LNUM »
          END
	  DUP 3 ==
          THEN
            « LSTR »
          END
        END 'LEE' STO 'TIPO' STO
      END
    »


* -----------------------------------------------------------------------
  TIPO
* -----------------------------------------------------------------------
    3


* -----------------------------------------------------------------------
  LEE
* -----------------------------------------------------------------------
    « LSTR »


* -----------------------------------------------------------------------
  ->CAR
* -----------------------------------------------------------------------
    « IP 10 /
      IF DUP 4.6 <=
      THEN
        DUP IP 1 - 6 * SWAP FP 10 * 1 - + 65 + CHR
      ELSE
        DUP IP 5 - 5 * SWAP FP 10 * 1 - + "!YZ?#_789/_456*_123-_0. +"
	SWAP 1 + DUP SUB
      END
    »


* -----------------------------------------------------------------------
  LCHR
* -----------------------------------------------------------------------
    « 1 SRECV DROP »


* -----------------------------------------------------------------------
  LNUM
* -----------------------------------------------------------------------
    « 1 SRECV DROP NUM ->STR »


* -----------------------------------------------------------------------
  LSTR
* -----------------------------------------------------------------------
    « ""
      DO
        1 SRECV DROP +
      UNTIL BUFLEN DROP 0 ==
      END
    »

En el web de Microbótica puede encontrarse documentación complementaria y ejemplos para comunicar tarjetas CT6811 y calculadoras HP.

• Programa ejemplo para el MC68HC11 (hp48c.asm).
• Fuentes de los programas para la HP-48 (texto, binario).

Esto es software libre y como tal se distribuye bajo licencia pública GNU (GPL). El código fuente de la HP-48 no guarda los cometarios pero puede consultar las licencias en este enlace para las condiciones de copia. No hay NINGUNA garantía; ni siquiera de COMERCIABILIDAD o IDONEIDAD PARA UN FIN DETERMINADO.